int CREATION_INTENSITY = 2;
double GRAVITY = 0.0;

Particles particles;
Obstacles obstacles;
WebcamMen webcamMen;
Webcam webcam;

Vector mouseParticles = new Vector();

int ms, lastMs, avFrameTime;
int[] frameTimeBuffer;
int MIN_FPS = 25;
int FPS = 35;
int FPS_BUFFER_FRAMES = 50;


void setup() {
  size(500,250,P3D);

  // CREATE PARTICLES:
  particles = new Particles();
  for (int i=0;i<1000;i++) {
    Particle p = new Particle(width*random(0.4,0.6),height*random(0.4,1.0));
    particles.addParticle(p);
  }

  // CREATE OBSTACLES:
  obstacles = new Obstacles();
  obstacles.add(new Obstacle(50,1,1,1));
  obstacles.add(new Obstacle(width-50,1,width-1,1));
  obstacles.add(new Obstacle(50,1,width-50,1));
  obstacles.add(new Obstacle(1,height-1,width-1,height-1));
  obstacles.add(new Obstacle(1,1,1,height-1));
  obstacles.add(new Obstacle(width-1,1,width-1,height-1));

  // CREATE WEBCAM SIMULATION
  webcam = new Webcam(width,height);
  webcamMen = new WebcamMen();
  
  ms=millis();
  frameTimeBuffer=new int[0];
  
}




void keyPressed() {
  GRAVITY=0.8;
}
void keyReleased() {
  GRAVITY=0.0;
}





void draw() {
  // advance webcam simulation
  webcamMen.draw();
  webcamMen.setPixelsTo(this,webcam);
  background(255);
  
  
  // show webcam input:
  image(webcam,0,0);
  
  // webcam to particles:
  webcam.imageToParticleVector(particles);

  // add particles with right mouse click
  if (mousePressed&&mouseButton==RIGHT) {
    if (pmouseX!=mouseX||pmouseY!=mouseY) {
      Vec mouse = new Vec(Vec.MOUSE);
      Vec pmouse = new Vec(Vec.PMOUSE);
      Vec dis = vecSub(mouse,pmouse);
      double d = (vecSub(mouse,pmouse)).len()/Particle.MAX_INFLUENCE_RANGE;
      double pd = 1.0/d;
      for (double p=0;p<1.0;p+=pd) {
        for (int i=0;i<CREATION_INTENSITY;i++) {
          Particle prt = new Particle(vecAdd(pmouse,vecMul(dis,p)));
          particles.addParticle(prt);
        }
      }
    } 
    else {
      for (int i=0;i<CREATION_INTENSITY;i++) {
        Particle prt = new Particle(new Vec(Vec.MOUSE));
        particles.addParticle(prt);
      }
    }
  }

  particles.update(obstacles);
  obstacles.draw();
  particles.draw();
  
  openHatchForHigherFramerate();
}



void openHatchForHigherFramerate() {
  lastMs=ms;
  ms = millis();
  int frameTime=(ms-lastMs);
  if (frameTimeBuffer.length<FPS_BUFFER_FRAMES) {
    frameTimeBuffer = append(frameTimeBuffer,frameTime);
  } else {
    for (int i=0;i<frameTimeBuffer.length-1;i++) frameTimeBuffer[i]=frameTimeBuffer[i+1];
    frameTimeBuffer[frameTimeBuffer.length-1]=frameTime;
  }
  avFrameTime=0;
  for (int i=0;i<frameTimeBuffer.length;i++) avFrameTime += frameTimeBuffer[i];
  avFrameTime/=((float)frameTimeBuffer.length);
  float fps = 1000.0/avFrameTime;
  float deltaFPSPerParticle = fps/particles.size();
  
  if (fps<MIN_FPS&&frameTimeBuffer.length==FPS_BUFFER_FRAMES) {
    ((Obstacle)obstacles.elementAt(0)).ACTIVE=false;
    ((Obstacle)obstacles.elementAt(1)).ACTIVE=false;
  } else {
    ((Obstacle)obstacles.elementAt(0)).ACTIVE=true;
    ((Obstacle)obstacles.elementAt(1)).ACTIVE=true;
  }
  //println(nf(fps,1,3)+" fps");
}





// PLAY WITH WATER FUNCTIONS:
// left-click to interfere with particles
// (adds temporary invisible particles)

void mousePressed() {
  if (mouseButton==LEFT) {
    for (int x=-2;x<=2;x++) for (int y=-2;y<=2;y++) {
      Vec pos = new Vec(Vec.MOUSE);
      pos.add(Particle.MAX_INFLUENCE_RANGE*x*1.2,Particle.MAX_INFLUENCE_RANGE*y*1.2);
      Particle particle = new Particle(pos);
      particle.UNMOVABLE=true;
      particle.VISIBLE=false;
      particle.REMOVABLE_FOR_FRAMERATE=false;
      particles.addParticle(particle);
      mouseParticles.add(particle);
    }
  }
}

void mouseDragged() {
  for (int i=0;i<mouseParticles.size();i++) 
    ((Particle)mouseParticles.elementAt(i)).pos.add(vecSub(new Vec(Vec.MOUSE),new Vec(Vec.PMOUSE)));
}

void mouseReleased() {
  for (int i=0;i<mouseParticles.size();i++) 
    particles.remove((Particle)mouseParticles.elementAt(i));
  mouseParticles.clear();
}