class Obstacles extends Vector {

  Obstacles() {
    super();
  }




  private double travelToObstacle(Vec start, Vec end, double _totalWallDrag) {
    double totalWallDrag = _totalWallDrag;

    // FIND CLOSEST OBSTACLE: 
    // Particle p & this -> Obstacle closestObstacle & Vec closestIntersectionPoint
    double closestDistance = 999999;

    Vec closestIntersectionPoint = new Vec();
    Obstacle closestObstacle = null;

    for (int i=0;i<size();i++) {
      Obstacle obstacle = (Obstacle)elementAt(i);
      if (obstacle.ACTIVE) {
        Vec intersectionPoint = obstacle.getIntersectionPoint(start,end);
        if (intersectionPoint!=null) {
          double dToIntersection = (vecSub(intersectionPoint,start)).len();
          if (dToIntersection<closestDistance) {
            closestDistance = dToIntersection;
            closestIntersectionPoint.set(intersectionPoint);
            closestObstacle = new Obstacle(obstacle);
          }
        }
      }
    }

    if (closestObstacle!=null) {
      // introduce rolling here!
      Vec afterMov = vecSub(end,closestIntersectionPoint);
      afterMov.mul(closestObstacle.WALL_DRAG);
      afterMov.rotZ(-closestObstacle.dir);
      afterMov.Y *= -1;
      afterMov.rotZ(closestObstacle.dir);
      start.set(closestIntersectionPoint);
      Vec miniAdd = new Vec(afterMov);
      miniAdd.setLen(0.00000001);
      start.add(miniAdd);

      end.set(vecAdd(start,afterMov));
      totalWallDrag *= closestObstacle.WALL_DRAG;      
      totalWallDrag = travelToObstacle(start,end,totalWallDrag);

    }

    return totalWallDrag;
  }




  public void interfereWith(Particle p) {

    Vec start = new Vec(p.pos);
    Vec end = new Vec(p.newPos);
    Obstacle lastObstacle = null;

    double totalWallDrag = travelToObstacle(start,end,1.0);  // RECURSIVE!

    Vec newMov = vecSub(end,start);
    newMov.setLen(p.newMov.len()*totalWallDrag);    

    p.newPos.set(end);
    p.newMov.set(newMov);

  }




  public void draw() {
    stroke(0);
    for (int i=0;i<size();i++) ((Obstacle)elementAt(i)).draw();
  }

}