class WebcamMan {
  float x,y;
  float speed, targetSpeed;
  float scl;
  float freq, bounce;
  float armSwing, legSwing;
  float goChance, stopChance, revDirChance;
  float ms;
  float targetTimeFac = 1.0;
  float timeFac = 1.0;
  boolean walk = true;

  WebcamMan(float _x, float _y, float _speed, float _scl,float _freq,float _bounce,float _arm, float _leg, float go, float stop, float revDir) {
    x=_x;
    y=_y;
    speed = _speed;
    scl = _scl;
    freq = _freq;
    bounce = _bounce;
    armSwing = _arm;
    legSwing = _leg;
    goChance = go;
    stopChance = stop;
    revDirChance = revDir;
    ms =0;
  }

  void stop() {
    targetTimeFac = 0;
  }

  void go() {
    targetTimeFac = 1.0;
  }

  void revDir() {
    targetTimeFac *= -1;
  }

  void draw(float step) {
    timeFac = 0.9*timeFac+0.1*targetTimeFac;
    x+=timeFac*step*speed;
    if (x<-50) x=width+50;
    else if (x>width+50) x=-50;
    ms += timeFac*step*40;

    if (walk) {
      walk = random(1.0)>stopChance;
      if (!walk) stop();
    }
    else {
      walk = random(1.0)<goChance;
      if (walk) go();
    }
    if (random(1.0)<revDirChance) revDir();


    pushMatrix();
    translate(x,y);
    pushMatrix();
    scale(scl);
    translate(0,-bounce*sin(2*freq*ms/1000.0+PI/2.0));
    // head:
    fill(0xfffab572);
    ellipse(0,-50,15,15);
    //arm bottom
    fill(0xFF1c4e0c);
    pushMatrix();
    translate(0,-30);
    rotateZ(armSwing*-sin(freq*ms/1000.0+0.3));
    translate(0,30);
    ellipse(0,0,10,35);
    popMatrix();
    //l;eg bottom
    fill(0xff2163c7);
    pushMatrix();
    translate(0,30);
    rotateZ(legSwing*sin(freq*ms/1000.0));
    translate(0,30);
    ellipse(0,0,10,35);
    popMatrix();
    //body
    fill(0xff286913);
    ellipse(0,0,15,35);
    // leg top
    fill(0xff2d77e6);
    pushMatrix();
    translate(0,30);
    rotateZ(legSwing*-sin(freq*ms/1000.0));
    translate(0,30);
    ellipse(0,0,10,35);
    popMatrix();
    //arm top
    fill(0xFF34831b);
    pushMatrix();
    translate(0,-30);
    rotateZ(armSwing*sin(freq*ms/1000.0+0.3));
    translate(0,30);
    ellipse(0,0,10,35);
    popMatrix();
    popMatrix();
    popMatrix();
  }
}