import processing.opengl.*;


PFont font;
float BACK_HALFWIDTH = 50;
float FRONT_HALFWIDTH = 150;
float BACK_WALL = -800;
float BACK_HEIGHT = 200;
float FRONT_HEIGHT = 260;
float TV_TOP = -180;
float TV_HEIGHT = 92;

float CAM_X = 0;
float CAM_Y = -120;
float CAM_Z = 300;

float MAN_Z = -130;

float CLOSEST_POINT = -600;
float CLOSEST_Z;

float NICE_R = 150, NICE_G = 190, NICE_B = 255;
float GARB_R = 175, GARB_G = 154, GARB_B = 101;

float MOUSE_DOWN_X = 0;
float MOUSE_DOWN_Y = 0;

boolean HELPLINES = false;

PImage man;
PImage tv[];

void setup() {
  size(600,420,OPENGL);
  font = loadFont("ArialMT-48.vlw");
  textFont(font,24);

  PImage tmp = loadImage("HumanShape180.jpg");
  man = createImage(58,180,ARGB);
  for (int i=0;i<tmp.pixels.length;i++) {
    man.pixels[i]=tmp.pixels[i];
    if (red(tmp.pixels[i])>64) man.pixels[i] = 0x00|(man.pixels[i]&0xFFFFFF);
  }
  
  tv = new PImage[20];
  tv[0] = loadImage("Phone.jpg");
  tv[19] = loadImage("PhoneInGarbage.jpg");
  
  
  
  for (int p=1;p<19;p++) {
    float f1 = p/20.0;
    float f0 = 1.0-f1;
    tv[p] = new PImage(tv[0].width,tv[0].height);
    for (int i=0;i<tv[0].pixels.length;i++) {
      int c0 = tv[0].pixels[i];
      int c1 = tv[19].pixels[i];
      int r = (int) (f0*(c0>>16&0xFF) + f1*(c1>>16&0xFF));
      int g = (int) (f0*(c0>>8&0xFF) + f1*(c1>>8&0xFF));      
      int b = (int) (f0*(c0&0xFF) + f1*(c1&0xFF));
      tv[p].pixels[i]=color(r,g,b);
    }
    
  }
  
  noStroke();

}

void mousePressed() {
  MOUSE_DOWN_X = mouseX;
  MOUSE_DOWN_Y = mouseY;
}

void mouseReleased() {
  CAM_X += MOUSE_DOWN_X-mouseX;
  CAM_Y += MOUSE_DOWN_Y-mouseY;
}

void keyPressed() {
  if (keyCode==UP) CAM_Z -= 7;
  if (keyCode==DOWN) CAM_Z += 7;
  
  if (key=='q') MAN_Z -= 7;
  if (key=='a') MAN_Z += 7;
  
  if (key=='S') saveFrame("RoomDesign1_#####.tga");
}

void draw() {
  
  CLOSEST_Z = (CAM_Z<MAN_Z?CAM_Z:MAN_Z);
  
  float normToGarbage = max(min(CLOSEST_Z,0),CLOSEST_POINT)/CLOSEST_POINT;  // 0..1
  int tvFade = (int)((tv.length-1)*normToGarbage);
  
  //println(tvFade);
  
  float tvBrightness = random(0.95,1.0);
  //tvBrightness *= (1.0-normToGarbage*.3);
  
  float tvR = tvBrightness * (NICE_R + normToGarbage*(GARB_R-NICE_R));
  float tvG = tvBrightness * (NICE_G + normToGarbage*(GARB_G-NICE_G));
  float tvB = tvBrightness * (NICE_B + normToGarbage*(GARB_B-NICE_B));
  
  background(0);
  rectMode(CORNER);
  
  //lights();
  float ambientBright = 64 * (1.0-normToGarbage*0.8);
  ambientLight(ambientBright,ambientBright,ambientBright,   0,-500,BACK_WALL/2);
  
  // TVLIGHT
  spotLight(tvR,tvG,tvB,  0,TV_TOP+TV_HEIGHT/2.0,BACK_WALL+200,  0,TV_TOP+TV_HEIGHT,BACK_WALL,  PI*.07, 1);
  spotLight(tvR,tvG,tvB,  0,TV_TOP+TV_HEIGHT/2.0,BACK_WALL+200,  0,TV_TOP+TV_HEIGHT,BACK_WALL,  PI*.07, 1);
  
  // ROOMLIGHT
  float r = .8;
  pointLight(tvR*r,tvG*r,tvB*r,  0,-BACK_HEIGHT*.5,BACK_WALL);
  r = .2;
  pointLight(tvR*r,tvG*r,tvB*r,  0,-BACK_HEIGHT*.5,0);
  //spotLight(tvR*r,tvG*r,tvB*r,  FRONT_HALFWIDTH,0,0,    -BACK_HALFWIDTH,-BACK_HEIGHT/2.0,BACK_WALL*.1,  PI*.5, 2);
  //spotLight(tvR*r,tvG*r,tvB*r,  -FRONT_HALFWIDTH,0,0,    BACK_HALFWIDTH,-BACK_HEIGHT/2.0,BACK_WALL*.1,  PI*.5, 2);
  
  //spotLight(tvR*r,tvG*r,tvB*r,  -FRONT_HALFWIDTH,0,0,    BACK_HALFWIDTH,-BACK_HEIGHT,BACK_WALL,  PI/8.0, 1);
  //pointLight(50,55,64,  FRONT_HALFWIDTH,-BACK_HEIGHT/2,0);
  //pointLight(50,55,64,  -FRONT_HALFWIDTH,-BACK_HEIGHT/2,0);
  

  if (mousePressed||frameCount==1) {
    camera(CAM_X+MOUSE_DOWN_X-mouseX,CAM_Y+MOUSE_DOWN_Y-mouseY,CAM_Z,0,TV_TOP+TV_HEIGHT/2.0,BACK_WALL,0,1,0);
  } else {
    camera(CAM_X,CAM_Y,CAM_Z,0,TV_TOP+TV_HEIGHT/2.0,BACK_WALL,0,1,0);
  }


  beginShape(QUADS);

  // FULL FLOOR:
  fill(128);
  vertex(-1000,1,200);
  vertex(-1000,1,-1500);
  vertex(1000,1,-1500);
  vertex(1000,1,200);

  fill(255);
  // LEFT WALL:
  vertex(-FRONT_HALFWIDTH,0,0);
  vertex(-BACK_HALFWIDTH,0,BACK_WALL);
  vertex(-BACK_HALFWIDTH,-BACK_HEIGHT,BACK_WALL);
  vertex(-FRONT_HALFWIDTH,-FRONT_HEIGHT,0);

  fill(255);
  // RIGHT WALL:
  vertex(FRONT_HALFWIDTH,0,0);
  vertex(BACK_HALFWIDTH,0,BACK_WALL);
  vertex(BACK_HALFWIDTH,-BACK_HEIGHT,BACK_WALL);
  vertex(FRONT_HALFWIDTH,-FRONT_HEIGHT,0);

  // BACK WALL
  fill(255);
  vertex(-BACK_HALFWIDTH,0,BACK_WALL);
  vertex(-BACK_HALFWIDTH,-BACK_HEIGHT,BACK_WALL);
  vertex(BACK_HALFWIDTH,-BACK_HEIGHT,BACK_WALL);
  vertex(BACK_HALFWIDTH,0,BACK_WALL);
  
  // CEILING
  fill(255);
  vertex(-BACK_HALFWIDTH,-BACK_HEIGHT,BACK_WALL);
  vertex(BACK_HALFWIDTH,-BACK_HEIGHT,BACK_WALL);
  vertex(FRONT_HALFWIDTH,-FRONT_HEIGHT,0);
  vertex(-FRONT_HALFWIDTH,-FRONT_HEIGHT,0);
  
  // FLOOR
  fill(255);
  vertex(-BACK_HALFWIDTH,0,BACK_WALL);
  vertex(BACK_HALFWIDTH,0,BACK_WALL);
  vertex(FRONT_HALFWIDTH,0,0);
  vertex(-FRONT_HALFWIDTH,0,0);
  
  // TV FRAME
  fill(128);
  vertex(-33-5,TV_TOP-5,BACK_WALL+1);  
  vertex(33+5,TV_TOP-5,BACK_WALL+1);  
  vertex(33+5,TV_TOP+TV_HEIGHT+5,BACK_WALL+1);  
  vertex(-33-5,TV_TOP+TV_HEIGHT+5,BACK_WALL+1);  

  endShape();
  
  
  textureMode(NORMALIZED);
  beginShape();
  // TV:
  //fill(255*tvBrightness);
  texture(tv[tvFade]);
  vertex(-33,TV_TOP,BACK_WALL+2,0,0);  
  vertex(33,TV_TOP,BACK_WALL+2,1,0);  
  vertex(33,TV_TOP+TV_HEIGHT,BACK_WALL+2,1,1);  
  vertex(-33,TV_TOP+TV_HEIGHT,BACK_WALL+2,0,1);  
  endShape();

  // MAN1
  pushMatrix();
  translate(70 + (MAN_Z/10),-180,MAN_Z);
  image(man,0,0);
  popMatrix();
  
  // MAN2
  pushMatrix();
  translate(-140,-180,80);
  image(man,0,0);
  popMatrix();
  

  if (HELPLINES) {

    pushMatrix();
    translate(-200,0,0);
    fill(0);
    rotateY(HALF_PI);
    text("X: -200",0,0);
    line(-500,0,500,0);
    popMatrix();

    pushMatrix();
    translate(200,0,0);
    fill(0);
    rotateY(HALF_PI);
    text("X: 200",0,0);
    line(-500,0,500,0);
    popMatrix();

    pushMatrix();
    translate(0,0,-400);
    line(-500,0,500,0);
    fill(0);
    text("Z: -400",-250,0);
    popMatrix();

    text("Z: 0",-250,0);
    line(-500,0,500,0);

  }
}