class Terrain {
  int wid, dep;
  float[][] altitude;
  float fullWid, fullDep;
  float divSize;
  
  Terrain(int _wid, int _dep, float _divSize) {
    wid = _wid;
    dep = _dep;
    divSize = _divSize;
    fullWid = wid*(divSize-1);
    fullDep = dep*(divSize-1);
    altitude = new float[wid][dep];
    for (int i=0;i<wid;i++) {
      for (int j=0;j<dep;j++) {
        altitude[i][j] = 0;
      }
    }
  }
  
  void flat() {
    for (int i=0;i<wid;i++) {
      for (int j=0;j<dep;j++) {
        altitude[i][j] = 0;
      }
    }
  }
  
  void makeCosHole(float heightVar) {
    for (int i=0;i<wid;i++) {
      for (int j=0;j<dep;j++) {
        float cx = 0.5 + 0.5*cos(TWO_PI*i/(float)wid);
        float cy = 0.5 + 0.5*cos(TWO_PI*j/(float)dep);
        altitude[i][j] = -heightVar * (cx + cy);
      }
    }
  }
  
  void addRandom(float heightVar) {
    for (int i=0;i<wid;i++) {
      for (int j=0;j<dep;j++) {
        altitude[i][j] += -heightVar * (noise(5*i/(float)wid,5*j/(float)dep)-0.5);
      }
    }
  }
  
  void lower(float heightVar) {
    for (int i=0;i<wid;i++) {
      for (int j=0;j<dep;j++) {
        altitude[i][j] += heightVar;
      }
    }
  }
  
  
  void translateAll() {
    translate(-fullWid*0.5,0,-fullDep);
  }
  
  void lightAll() {
    pointLight(255,255,255,fullWid*0.5,-800,fullDep);
  }
  
  float getAltitudeAt(float _x, float _z) {
    //float out = 0;
    
    int ix0 = (int)(_x/divSize);
    if (ix0<0) ix0=0;
    if (ix0>=wid-1) ix0=wid-2;
    int ix1 = ix0 + 1;
    
    int iz0 = (int)(_z/divSize);
    if (iz0<0) iz0=0;
    if (iz0>=dep-1) iz0=dep-2;
    int iz1 = iz0 + 1;
    
    // code from: 
    // Finding the altitude of a point on a 3D grid.doc
    
    float yA = altitude[ix0][iz0];
    float yB = altitude[ix1][iz0];
    float yC = altitude[ix0][iz1];
    float yD = altitude[ix1][iz1];
    
    float z = _z - iz0*divSize;
    float zDivSizeZ = z/divSize;
    float y1 = yA + (yC-yA)*zDivSizeZ;
    float m = ((yB + (yD-yB)*zDivSizeZ)-(yA + (yC-yA)*zDivSizeZ))/divSize;
    float x = _x - ix0*divSize;
    float yp = y1 + m * x;	// definition of a line

    return yp;
  }
  
  void draw() {
    stroke(64,32,0);
    fill(128,64,0);    
    beginShape(QUADS);
    for (int i=0;i<wid-1;i++) {
      for (int j=0;j<dep-1;j++) {
        vertex(i*divSize,altitude[i][j],j*divSize);
        vertex((i+1)*divSize,altitude[i+1][j],j*divSize);
        vertex((i+1)*divSize,altitude[i+1][j+1],(j+1)*divSize);
        vertex(i*divSize,altitude[i][j+1],(j+1)*divSize);
      }
    }
    endShape();
  }
  
}